1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import QtQuick
import Quickshell.Io
import "../.."
// Not always active: the 2s stats poll exists only to paint a page nobody is
// looking at, so the page starts and stops it. The lifecycle event stream in
// Virsh is separate and always runs, which is what keeps the tile's dots and
// the VM list correct without polling.
Module {
id: mod
name: "vm"
icon: ""
label: "VMs"
alwaysActive: false
tileContent: Component { VmTile {} }
page: Component {
Page {
title: "VMs and containers"
VmPage { width: parent.width }
}
}
// An action that fails (libvirt refusing, a disk in use) has to say so:
// the notification is the only feedback, since virsh output goes nowhere.
property Process notifyProc: Process {}
function notify(target, action, message) {
notifyProc.command = ["notify-send", "--app-name=vm-manager",
"--urgency=critical", "--icon=error",
`${action} failed: ${target}`, message];
notifyProc.running = false;
notifyProc.running = true;
}
property Connections conn: Connections {
target: Virsh
// A start that fails in migrate-incoming is a managed save QEMU will
// not restore (an fd: save under a QEMU that wants file:), and it
// fails the same way every time, so say what to do about it.
function onActionFailed(vm, action, message) {
if (action === "start" && message.includes("migrate-incoming"))
message = "Its saved state can't be restored. Discard saved state on the VMs page, "
+ "then start it again: it boots cold, the disk is untouched.\n\n" + message;
mod.notify(vm, action, message);
}
}
property Connections dockerConn: Connections {
target: Docker
function onActionFailed(target, action, message) { mod.notify(target, "docker " + action, message); }
}
}
|
