1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import QtQuick
import "../.."
// One labelled key of qtmaildir.conf: a text field that edits the draft as
// it is typed; the page's Save writes it. Emptied, the key is unset and
// qtmaildir uses its default, which the placeholder names. kind "int" or
// "float" checks the number and its range: a refused value stays out of the
// draft, shows why under the row, and holds Save back until it is fixed.
Column {
id: s
property string section
property string key
property string label
property string placeholder: ""
property string hint: ""
property string kind: "text"
property real min: -Infinity
property real max: Infinity
// A #rrggbb key: a swatch beside the field opens a colour dialog.
property bool colour: false
// What a search hit scrolls to.
objectName: section + "/" + key
width: parent ? parent.width : 0
spacing: 2
readonly property string value: Qtm.get(s.section, s.key) ?? ""
property string problem: ""
function apply(t) {
t = t.trim();
let bad = "";
if (t !== "" && s.kind !== "text") {
const n = Number(t);
if (isNaN(n) || (s.kind === "int" && !Number.isInteger(n)) || n < s.min || n > s.max)
bad = s.kind === "int" ? `a whole number from ${s.min} to ${s.max}`
: `a number from ${s.min} to ${s.max}`;
}
s.problem = bad;
Qtm.markInvalid(s.objectName, bad !== "");
if (bad === "") Qtm.set(s.section, s.key, t === "" ? null : t);
}
// The field is not bound to the value, which would reset the cursor and
// eat a typed trailing space; it follows the value only when the draft
// moves under it (Discard, a colour picked, a save of another page).
onValueChanged: if (ti.text.trim() !== s.value && s.problem === "") ti.text = s.value
Connections {
target: Qtm
function onInvalidChanged() { if (s.problem !== "" && !Qtm.invalid[s.objectName]) { s.problem = ""; ti.text = s.value; } }
}
// A field that goes away cannot hold Save back; the draft keeps its last
// good value.
Component.onDestruction: Qtm.markInvalid(s.objectName, false)
Item {
width: s.width
height: 34
Text {
id: lbl
anchors { left: parent.left; verticalCenter: parent.verticalCenter }
width: 160
elide: Text.ElideRight
text: s.label
color: Theme.subtext
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
}
ColourPick {
id: pick
anchors { right: parent.right; verticalCenter: parent.verticalCenter }
visible: s.colour
width: s.colour ? 34 : 0
colour: s.value
onPicked: hex => s.apply(hex)
}
Rectangle {
anchors { left: lbl.right; leftMargin: 8; right: pick.left; rightMargin: s.colour ? 8 : 0
top: parent.top; bottom: parent.bottom }
radius: 8
color: Theme.surface
TextInput {
activeFocusOnTab: true
id: ti
anchors { fill: parent; leftMargin: 10; rightMargin: 10 }
verticalAlignment: TextInput.AlignVCenter
clip: true
selectByMouse: true
color: Theme.text
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 2 }
Component.onCompleted: text = s.value
onTextEdited: s.apply(text)
Text {
anchors.verticalCenter: parent.verticalCenter
width: parent.width
elide: Text.ElideRight
visible: parent.text === ""
text: s.placeholder
color: Theme.overlay
font: parent.font
}
}
}
}
Text {
x: 168
width: s.width - x
visible: s.problem !== "" || s.hint !== ""
wrapMode: Text.Wrap
text: s.problem !== "" ? "Must be " + s.problem + "." : s.hint
color: s.problem !== "" ? Theme.red : Theme.overlay
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 5 }
}
}
|
