1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import Quickshell
import QtQuick
import "../.."
import "../appearance"
import "../qtmaildir"
// The rows of the notifications settings page. Everything edits mod.draft.
Column {
id: pg
// Not "nm": a property named like the injecting id binds to itself.
required property QtObject mod
readonly property var d: mod.draft
spacing: 8
function setTimeout(key, v) {
pg.mod.edit({ timeouts: Object.assign({}, pg.d.timeouts, { [key]: v }) });
}
Heading { text: "Timeouts" }
Text {
width: pg.width; wrapMode: Text.Wrap
text: "Seconds a balloon stays when the app leaves it to the daemon. An app's own timeout still wins."
color: Theme.overlay
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
}
Repeater {
model: [["low", "Low"], ["normal", "Normal"], ["critical", "Critical"]]
Row {
required property var modelData
spacing: 10
Text {
width: 90; anchors.verticalCenter: parent.verticalCenter
text: modelData[1]; color: Theme.text
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
}
Field {
anchors.verticalCenter: parent.verticalCenter
visible: pg.d.timeouts[modelData[0]] !== 0
value: String(pg.d.timeouts[modelData[0]])
placeholder: "seconds"
// Typing drops the value binding too: put it back so Discard
// shows the draft, and a rejected entry reverts at once.
onEdited: {
const n = parseInt(value, 10);
value = Qt.binding(() => String(pg.d.timeouts[modelData[0]]));
if (n > 0 && n <= 86400) pg.setTimeout(modelData[0], n);
}
}
Toggle {
anchors.verticalCenter: parent.verticalCenter
label: "never"
checked: pg.d.timeouts[modelData[0]] === 0
// Toggle flips itself on click, which drops the binding; put
// it back so Discard shows the draft again.
onToggled: {
const on = checked;
checked = Qt.binding(() => pg.d.timeouts[modelData[0]] === 0);
pg.setTimeout(modelData[0], on ? 0 : 10);
}
}
}
}
Heading { text: "Limits" }
Text {
width: pg.width; wrapMode: Text.Wrap
text: "How many notifications are kept live and in history, 1 to 100 each. Past the live limit the oldest moves to history; past the history limit it is dropped."
color: Theme.overlay
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
}
Repeater {
model: [["liveCap", "On screen"], ["historyCap", "History"]]
Row {
required property var modelData
spacing: 10
Text {
width: 90; anchors.verticalCenter: parent.verticalCenter
text: modelData[1]; color: Theme.text
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
}
Field {
anchors.verticalCenter: parent.verticalCenter
value: String(pg.d[modelData[0]])
border.color: pg.d[modelData[0]] >= 1 && pg.d[modelData[0]] <= 100 ? Qt.alpha(Theme.text, 0.12) : Theme.red
onEdited: {
const n = parseInt(value, 10) || 0;
value = Qt.binding(() => String(pg.d[modelData[0]]));
pg.mod.edit({ [modelData[0]]: n });
}
}
}
}
Heading { text: "Placement" }
Flow {
width: pg.width; spacing: 6
Repeater {
model: Quickshell.screens.map(s => s.name)
Button {
required property string modelData
text: modelData
border.color: pg.d.balloons.screen === modelData ? Theme.accent : Qt.alpha(Theme.text, 0.2)
onClicked: pg.mod.edit({ balloons: Object.assign({}, pg.d.balloons, { screen: modelData }) })
}
}
}
// The four corners as a miniature screen: click the one balloons go to.
Grid {
columns: 2; spacing: 4
Repeater {
model: ["top-left", "top-right", "bottom-left", "bottom-right"]
Rectangle {
required property string modelData
width: 60; height: 34; radius: 5
color: pg.d.balloons.corner === modelData ? Qt.alpha(Theme.accent, 0.6) : Qt.alpha(Theme.surface, 0.6)
border.width: 1; border.color: Qt.alpha(Theme.text, 0.15)
MouseArea {
anchors.fill: parent; cursorShape: Qt.PointingHandCursor
onClicked: pg.mod.edit({ balloons: Object.assign({}, pg.d.balloons, { corner: modelData }) })
}
}
}
}
Heading { text: "Suppression" }
Toggle {
label: "Critical notifications still pop up under Do Not Disturb"
checked: pg.d.dndPassCritical
onToggled: {
const on = checked;
checked = Qt.binding(() => pg.d.dndPassCritical);
pg.mod.edit({ dndPassCritical: on });
}
}
Text {
width: pg.width; wrapMode: Text.Wrap
text: "Muted apps get no balloon. They still appear in the drawer and in history."
color: Theme.overlay
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
}
// Two rows told apart by a caption and by look: muted apps in red, a
// click unmutes; recent apps dimmed, a click mutes.
Text {
text: pg.d.muted.length ? "Muted, click to unmute" : "No muted apps"
color: Theme.subtext
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4; bold: true }
}
Flow {
width: pg.width; spacing: 6
Repeater {
model: pg.d.muted
Button {
required property string modelData
text: modelData; icon: "\uf00d"; danger: true
onClicked: pg.mod.edit({ muted: pg.d.muted.filter(a => a !== modelData) })
}
}
}
// Apps seen in the queue and history, newest first (both lists are), not
// yet muted. Bounded by the two caps already; the slice keeps the row short.
Text {
visible: recent.count > 0
topPadding: 6
text: "Recently seen, click to mute"
color: Theme.subtext
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4; bold: true }
}
Flow {
width: pg.width; spacing: 6
Repeater {
id: recent
model: [...new Set(Notify.queue.concat(Notify.history).map(n => n.app))]
.filter(a => a && pg.d.muted.indexOf(a) < 0).slice(0, 8)
Button {
required property string modelData
text: modelData; icon: "\uf067"
opacity: 0.7
onClicked: pg.mod.edit({ muted: pg.d.muted.concat([modelData]) })
}
}
}
Field {
width: 200
placeholder: "mute another app by name"
onEdited: {
const a = value.trim();
if (a !== "" && pg.d.muted.indexOf(a) < 0) pg.mod.edit({ muted: pg.d.muted.concat([a]) });
value = "";
}
}
Text {
width: pg.width; wrapMode: Text.Wrap
visible: pg.mod.notice !== ""
text: pg.mod.notice
color: pg.mod.notice === "saved" ? Theme.green : Theme.yellow
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
}
}
|
