1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import QtQuick
import "../.."
// The wallpaper engine's page: on or off, the interval, and the two lists.
Module {
name: "wallengine"
label: "Wallpaper engine"
// nf-fa-shuffle, present in Inconsolata Nerd Font.
icon: "\uf074"
settings: true
dirty: WallEngine.dirty
group: "Appearance"
keywords: ["wallpaper", "timer", "rotate", "rotation", "shuffle", "slideshow", "heart"]
// A singleton is built on first use, and the engine's timer has to run
// from the start of the session, page opened or not. Modules exist for
// the whole session, so this reference is what starts it.
readonly property bool engineOn: WallEngine.on
page: Component {
Page {
title: "Wallpaper engine"
// SaveBar's place, not SaveBar: the engine is started and stopped
// here as well as saved, and its state is what the header reports.
actions: Component {
Row {
spacing: 8
Text {
id: status
// Only ticks while the page is open: the engine
// itself keeps nextAt, not a count.
property double now: Date.now()
Timer {
interval: 1000
repeat: true
running: WallEngine.on
triggeredOnStart: true
onTriggered: status.now = Date.now()
}
// Floored, as now can be up to a second old: a
// restarted timer reads the full interval, not one
// second over it. Not named left: that is Item's
// anchor line, which a function cannot shadow.
function remaining() {
const s = Math.max(0, Math.floor((WallEngine.nextAt - now) / 1000));
const two = n => (n < 10 ? "0" : "") + n;
const h = Math.floor(s / 3600);
return (h > 0 ? h + ":" : "") + two(Math.floor(s / 60) % 60) + ":" + two(s % 60);
}
anchors.verticalCenter: parent.verticalCenter
text: WallEngine.dirty ? "unsaved changes"
: WallEngine.on ? "running, next change in " + remaining()
: "stopped"
color: WallEngine.dirty ? Theme.yellow : WallEngine.on ? Theme.green : Theme.overlay
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
}
Button {
visible: WallEngine.dirty
text: "Reset"
onClicked: WallEngine.reset()
}
Button {
visible: WallEngine.on
text: "Stop"
enabled: !Wallpapers.applying
onClicked: WallEngine.stop()
}
Button {
text: WallEngine.on ? "Apply" : "Start"
enabled: (!WallEngine.on || WallEngine.dirty) && !Wallpapers.applying
onClicked: WallEngine.on ? WallEngine.apply() : WallEngine.start()
}
}
}
WallEngineTab { width: parent.width }
}
}
}
|
