blob: 2950759ac47d3dac11a02dd4469dd6d914f98409 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import QtQuick
import "../.."
// One engine or app: a state dot, a name, a detail line, at most one
// button, and a Restart before it when restartable. An empty action means no
// button, which is every engine row.
Rectangle {
id: row
property string title
property string detail
property bool on: false
property bool busy: false
property string action: ""
property bool danger: false
property bool restartable: false
signal triggered
signal restart
implicitHeight: Math.max(texts.implicitHeight, btn.visible ? btn.implicitHeight : 0) + 16
radius: 8
color: row.on ? Qt.alpha(Theme.accent, 0.10) : Qt.alpha(Theme.surface, 0.35)
Rectangle {
id: dot
width: 8; height: 8; radius: 4
anchors { left: parent.left; leftMargin: 10; verticalCenter: parent.verticalCenter }
color: row.busy ? Theme.yellow : row.on ? Theme.green : Theme.subtext
}
Column {
id: texts
anchors {
left: dot.right; leftMargin: 10
right: restartBtn.visible ? restartBtn.left : btn.visible ? btn.left : parent.right
rightMargin: 10
verticalCenter: parent.verticalCenter
}
spacing: 2
Text {
width: parent.width
elide: Text.ElideRight
text: row.title
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 2; bold: row.on }
color: row.on ? Theme.text : Theme.subtext
}
Text {
width: parent.width
elide: Text.ElideRight
text: row.detail
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
color: Theme.subtext
}
}
Button {
id: restartBtn
anchors { right: btn.left; rightMargin: 6; verticalCenter: parent.verticalCenter }
visible: row.restartable
text: "Restart"
onClicked: row.restart()
}
Button {
id: btn
anchors { right: parent.right; rightMargin: 10; verticalCenter: parent.verticalCenter }
visible: row.action !== ""
text: row.action
danger: row.danger
onClicked: row.triggered()
}
}
|
