blob: faf24ddca4072d7117de61b4f539ba29c25e881b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import Quickshell
import Quickshell.Widgets
import Quickshell.Services.SystemTray
import QtQuick
import ".."
import "Logic.js" as Logic
// Volume icon, tray, layout flag. The volume icon is the only way into the
// sound panel and has no other gesture; the tray is a plain tray; the flag
// switches layout on scroll and ignores clicks.
Capsule {
id: pill
required property QtObject sound
// The island window, which tray menus are positioned against.
required property QtObject window
property string panel: ""
signal openSound()
signal openDrawer()
expanded: panel === "sound"
restWidth: restRow.implicitWidth + 24
panelWidth: 320
panelHeight: soundPanel.implicitHeight + 28
Row {
id: restRow
anchors.centerIn: parent
spacing: 12
opacity: pill.expanded ? 0 : 1
visible: opacity > 0
Behavior on opacity { NumberAnimation { duration: 120 } }
IconImage {
anchors.verticalCenter: parent.verticalCenter
implicitSize: 18
source: Quickshell.iconPath(Logic.volumeIcon(pill.sound.volume, pill.sound.muted), true)
MouseArea {
anchors.fill: parent
cursorShape: Qt.PointingHandCursor
onClicked: pill.openSound()
}
}
Repeater {
model: SystemTray.items.values
delegate: IconImage {
id: trayIcon
required property SystemTrayItem modelData
anchors.verticalCenter: parent.verticalCenter
implicitSize: 16
source: modelData.icon
MouseArea {
anchors.fill: parent
acceptedButtons: Qt.LeftButton | Qt.RightButton
cursorShape: Qt.PointingHandCursor
onClicked: mouse => {
const item = trayIcon.modelData;
const wantsMenu = mouse.button === Qt.RightButton || item.onlyMenu;
if (!wantsMenu) { item.activate(); return; }
if (!item.hasMenu) return;
const p = trayIcon.mapToItem(null, 0, trayIcon.height + 6);
item.display(pill.window, p.x, p.y);
}
}
}
}
Image {
anchors.verticalCenter: parent.verticalCenter
width: 18
height: 18
sourceSize: Qt.size(18, 18)
source: Qt.resolvedUrl("assets/" + Keyboard.flag)
WheelHandler {
onWheel: event => Keyboard.cycle(event.angleDelta.y > 0 ? "prev" : "next")
}
}
}
SoundPanel {
id: soundPanel
x: 14
y: 14
width: pill.panelWidth - 28
sound: pill.sound
opacity: pill.expanded ? 1 : 0
visible: opacity > 0
Behavior on opacity { NumberAnimation { duration: 160 } }
onOpenDrawer: pill.openDrawer()
}
}
|
