1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
|
// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
import Quickshell
import QtQuick
// The settings window: a normal toplevel, not a layer surface, so Hyprland
// tiles or floats it like any app. The drawer is the quick area; things set
// once and left alone live here. It hosts the pages of the modules that
// declare `settings: true`, from the same module list as the drawer, with a
// searchable list of them down the left and an About page as the landing.
Scope {
id: root
property list<QtObject> modules
property bool open: false
property string page: ""
readonly property var pages: {
const out = [];
for (let i = 0; i < root.modules.length; i++)
if (root.modules[i].settings) out.push(root.modules[i]);
return out;
}
property string query: ""
// The pages the search keeps, as {mod, hit}: hit is the keyword that
// matched when the label did not, shown under the entry.
readonly property var found: {
const q = root.query.trim().toLowerCase();
const out = [];
for (const m of root.pages) {
if (q === "" || m.label.toLowerCase().includes(q) || m.name.includes(q)) {
out.push({ mod: m, hit: "" });
continue;
}
const k = Array.from(m.keywords).find(w => w.toLowerCase().includes(q));
if (k !== undefined) out.push({ mod: m, hit: k });
}
return out;
}
// Null is the landing page.
readonly property QtObject current: root.pages.find(m => m.name === root.page) ?? null
// An unknown or empty name opens the landing page.
function show(name) { root.page = name; root.open = true; }
// One step out: a page to the landing page, the landing page closes.
function back() {
if (root.current) root.page = "";
else root.close();
}
function close() { root.open = false; root.page = ""; root.query = ""; }
LazyLoader {
active: root.open
FloatingWindow {
title: "Settings"
implicitWidth: 900
implicitHeight: 640
color: Theme.base
onClosed: root.close()
Item {
anchors.fill: parent
focus: true
Keys.onEscapePressed: root.back()
// Search: filters the list below by label and by each
// module's keywords, the settings buried in its page. Enter
// opens the first match; Escape clears, then steps out.
Rectangle {
id: search
anchors { top: parent.top; left: parent.left; margins: 12 }
width: 200
height: 34
radius: 8
color: Theme.surface
TextInput {
id: searchIn
anchors { fill: parent; leftMargin: 10; rightMargin: 10 }
verticalAlignment: TextInput.AlignVCenter
clip: true
selectByMouse: true
color: Theme.text
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 2 }
text: root.query
onTextEdited: root.query = text
onAccepted: if (root.found.length) root.page = root.found[0].mod.name
Keys.onEscapePressed: event => {
if (root.query !== "") root.query = "";
else event.accepted = false;
}
Text {
anchors.verticalCenter: parent.verticalCenter
visible: parent.text === ""
text: "Search settings"
color: Theme.subtext
font: parent.font
}
}
}
ListView {
id: side
anchors { top: search.bottom; left: parent.left; bottom: parent.bottom; margins: 12 }
width: 200
spacing: 4
model: root.found
delegate: Rectangle {
id: entry
required property var modelData
readonly property bool selected: root.current === modelData.mod
width: side.width
height: modelData.hit ? 46 : 36
radius: 8
color: selected ? Qt.alpha(Theme.accent, 0.22)
: area.containsMouse ? Qt.alpha(Theme.text, 0.06) : "transparent"
Text {
id: entryIcon
anchors { left: parent.left; leftMargin: 10; verticalCenter: parent.verticalCenter }
text: entry.modelData.mod.icon
font { family: Theme.iconFamily; pixelSize: Theme.fontSize }
color: Theme.text
}
Column {
anchors { left: entryIcon.right; leftMargin: 10; right: parent.right; rightMargin: 8
verticalCenter: parent.verticalCenter }
Text {
text: entry.modelData.mod.label
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 2 }
color: Theme.text
}
// Which buried setting matched, when the label did not.
Text {
visible: entry.modelData.hit !== ""
width: parent.width
elide: Text.ElideRight
text: entry.modelData.hit
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 5 }
color: Theme.subtext
}
}
MouseArea {
id: area
anchors.fill: parent
hoverEnabled: true
cursorShape: Qt.PointingHandCursor
onClicked: root.page = entry.modelData.mod.name
}
}
}
Text {
anchors { top: search.bottom; left: parent.left; margins: 12; leftMargin: 22 }
visible: root.found.length === 0
text: "Nothing matches"
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
color: Theme.subtext
}
Rectangle {
id: rule
anchors { top: parent.top; bottom: parent.bottom; left: side.right; leftMargin: 12 }
width: 1
color: Qt.alpha(Theme.text, 0.12)
}
// The landing page, where back returns to: what this shell is.
Column {
anchors { top: parent.top; right: parent.right; left: rule.right; margins: 16 }
visible: root.current === null
spacing: 12
Text {
height: 44
verticalAlignment: Text.AlignVCenter
text: "About"
font { family: Theme.fontFamily; pixelSize: Theme.fontSize + 2; bold: true }
color: Theme.text
}
Text {
width: Math.min(parent.width, 560)
wrapMode: Text.Wrap
textFormat: Text.PlainText
lineHeight: 1.25
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 2 }
color: Theme.text
text: "A desktop shell for Hyprland, built on Quickshell.\n\n"
+ "SUPER alone opens the drawer, the quick area: notifications, sound, "
+ "network, bluetooth, mail, VMs, performance, the clipboard and the "
+ "rest of what changes during the day. The island at the top of the "
+ "main screen carries the clock, volume, tray, keyboard layout and "
+ "calendar, and SUPER+Home opens the assistant.\n\n"
+ "This window holds what is set once and left alone. Pick a page on "
+ "the left, or search for a setting by name."
}
Text {
text: "GPLv2. Colours follow the wallpaper through unified-desktop-theme."
font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
color: Theme.subtext
}
}
Loader {
id: pageLoader
anchors { top: parent.top; right: parent.right; bottom: parent.bottom; left: rule.right; margins: 16 }
sourceComponent: root.current?.page ?? null
// The Page's back arrow steps out to the landing page,
// dismiss closes the window, and go() moves to another
// settings page by name.
onLoaded: {
if (item && item.back) item.back.connect(root.back);
if (item && item.dismiss) item.dismiss.connect(root.close);
if (item && item.go) item.go.connect(name => root.page = name);
}
Binding {
target: pageLoader.item
property: "icon"
value: root.current ? root.current.icon : ""
when: pageLoader.item !== null
}
}
}
}
}
}
|
