// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.

pragma Singleton

import Quickshell
import Quickshell.Io
import QtQuick

Singleton {
    id: root

    // Catppuccin Macchiato. Fixed, same base as unified-desktop-theme.
    readonly property color base: "#24273a"
    readonly property color surface: "#363a4f"
    readonly property color text: "#cad3f5"
    readonly property color subtext: "#a5adcb"
    readonly property color red: "#ed8796"

    // Tracks the wallpaper, like rofi and dunst do. Lavender until read.
    property color accent: "#b7bdf8"

    readonly property string fontFamily: "Noto Sans"
    readonly property int fontSize: 16

    // udt-accent writes one line: `* { accent: #rrggbbaa; }`
    FileView {
        path: `${Quickshell.env("HOME")}/.cache/wal/udt-accent.rasi`
        watchChanges: true
        onFileChanged: reload()
        onLoaded: {
            const m = text().match(/accent:\s*(#[0-9a-fA-F]{6})/);
            if (m) root.accent = m[1];
        }
    }
}