// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.

import QtQuick

// One labelled stat with an optional bar. A negative fraction means the
// figure is unavailable, so the bar is left out rather than drawn at zero.
Column {
    required property string label
    required property string value
    property real fraction: -1

    spacing: 4

    Text {
        text: label
        font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
        color: Theme.overlay
    }
    Text {
        text: value
        font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 1 }
        color: Theme.text
    }
    Rectangle {
        visible: fraction >= 0
        width: 150; height: 4; radius: 2
        color: Qt.alpha(Theme.text, 0.12)
        Rectangle {
            width: parent.width * Math.max(0, Math.min(1, fraction))
            height: parent.height; radius: parent.radius
            color: Theme.accent
            Behavior on width { NumberAnimation { duration: 200 } }
        }
    }
}