// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.

import QtQuick
import "../.."

// A true/false key, as a switch showing the effective value: the file's, else
// the default.
Item {
    id: s
    property string section
    property string key
    property string label
    property bool fallback: false
    property string hint: ""
    objectName: section + "/" + key
    width: parent ? parent.width : 0
    height: 34

    readonly property var raw: Qtm.get(s.section, s.key)
    readonly property bool on: s.raw === undefined ? s.fallback : s.raw === "true"

    Text {
        id: lbl
        anchors { left: parent.left; verticalCenter: parent.verticalCenter }
        width: 160
        elide: Text.ElideRight
        text: s.label
        color: Theme.subtext
        font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 3 }
    }
    Switch {
        id: sw
        anchors { left: lbl.right; leftMargin: 8; verticalCenter: parent.verticalCenter }
        checked: s.on
        onToggled: Qtm.set(s.section, s.key, checked ? "true" : "false")
    }
    Text {
        anchors { left: sw.right; leftMargin: 10; right: parent.right; verticalCenter: parent.verticalCenter }
        elide: Text.ElideRight
        text: s.hint
        color: Theme.overlay
        font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 5 }
    }
}