// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.

import Quickshell
import QtQuick
import "../.."
import "../qtmaildir"

// deck-it, the tablet dashboard: Server, the first of its four pages, with
// its state and Restart in the header. See README.md.
Module {
    id: mod
    name: "deckit"
    label: "Server"
    // nf-md-tablet, present in Inconsolata Nerd Font.
    icon: "󰓶"
    settings: true
    group: "deck-it"
    dirty: DeckIt.store.dirty
    keywords: ["deck-it", "tablet", "android", "stream deck", "adb", "wifi", "avnc", "wayvnc",
               "second monitor", "autostart", "display", "resolution", "port", "hyprland", "icon theme"]
    readonly property var fields: [
        ["autostart", "", "Start at login"], ["wifi", "address", "Wi-Fi address"],
        ["display", "enabled", "Second display"], ["display", "resolution", "Resolution"],
        ["display", "position", "Position"], ["display", "scale", "Scale"],
        ["display", "refresh", "Refresh"], ["display", "name", "Output name"],
        ["ports", "command_center", "Dashboard port"], ["ports", "display", "Display port"],
        ["modules", "tabs", "Tabs"], ["", "hyprland", "Hyprland config"], ["icons", "theme", "Fallback icon theme"]]
    searchItems: fields.map(f => ({ text: f[2], key: f[0] + "/" + f[1] }))
    function refresh() { DeckIt.reload(); }

    page: Component {
        Page {
            title: "Server"
            // Its state in the header, as the Wallpaper engine page does:
            // `deck-it status`, polled while the page is open (DeckIt.watchers).
            // One draft behind all four deck-it pages: Save writes them all.
            actions: Component {
                Row {
                    spacing: 8
                    Text {
                        anchors.verticalCenter: parent.verticalCenter
                        // ponytail: a long summary elides; the header has one line.
                        width: Math.min(implicitWidth, 420)
                        elide: Text.ElideRight
                        text: DeckIt.summary
                        color: DeckIt.healthy ? Theme.green
                             : DeckIt.status && (DeckIt.status.server || DeckIt.status.waiting) ? Theme.yellow
                             : Theme.red
                        font { family: Theme.fontFamily; pixelSize: Theme.fontSize - 4 }
                    }
                    Button {
                        text: DeckIt.restartAt ? "Restarting…" : "Restart"
                        enabled: !DeckIt.restartAt
                        onClicked: DeckIt.restart()
                    }
                    SaveBar {
                        dirty: DeckIt.store.dirty; valid: DeckIt.store.valid; error: DeckIt.store.error
                        onSave: DeckIt.save(); onDiscard: DeckIt.store.discard()
                    }
                }
            }
            DeckItGeneralPage { width: parent.width }
        }
    }
}