// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License version 2 as
// published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.

import QtQuick
import "../.."

// The wallpaper picker. The thumbnail list scrolls itself, so the tab gets the
// page's visible height instead of the page's scroll.
Module {
    name: "wallpaper"
    label: "Wallpaper"
    // nf-fa-picture_o, present in Inconsolata Nerd Font.
    icon: "\uf03e"
    settings: true
    dirty: Wallpapers.dirty
    group: "Appearance"
    keywords: ["background", "screen", "monitor", "wallp", "wallhaven", "horizontal", "vertical"]

    function refresh() { Wallpapers.refresh(); }

    page: Component {
        Page {
            id: pg
            title: "Wallpaper"
            actions: Component {
                SaveBar {
                    id: bar
                    saveText: "Apply"; discardText: "Reset"; dirty: Wallpapers.dirty; busy: Wallpapers.applying
                    onSave: { bar.error = ""; Wallpapers.apply(); }
                    onDiscard: { bar.error = ""; Wallpapers.clearPending(); }
                    // A success closes the window, so only a failure is reported.
                    Connections {
                        target: Wallpapers
                        function onApplied(ok, message) { bar.error = ok ? "" : `wallpaper failed: ${message}`; }
                    }
                }
            }
            WallpaperTab { width: parent.width; height: pg.viewHeight; onDismiss: pg.dismiss() }
        }
    }
}