From 26277c179016b86b95d9f8185dab9dfed4474fc6 Mon Sep 17 00:00:00 2001
From: "Danilo M." <danix@danix.xyz>
Date: Mon, 14 Sep 2026 12:06:17 +0200
Subject: feat(desktop): tile and page chrome

The page body scrolls because mail with several accounts and vm with
several VMs both exceed the drawer height; the tile grid deliberately
does not, being fixed at a 3x3 ceiling.
---
 desktop/Page.qml | 76 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 desktop/Page.qml

(limited to 'desktop/Page.qml')

diff --git a/desktop/Page.qml b/desktop/Page.qml
new file mode 100644
index 0000000..0c29806
--- /dev/null
+++ b/desktop/Page.qml
@@ -0,0 +1,76 @@
+// Copyright (C) 2026 Danilo M. <danix@danix.xyz>
+//
+// This program is free software; you can redistribute it and/or modify
+// it under the terms of the GNU General Public License version 2 as
+// published by the Free Software Foundation.
+//
+// This program is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+// GNU General Public License for more details.
+
+import QtQuick
+import QtQuick.Controls
+
+Item {
+    id: page
+
+    property string title: ""
+    default property alias content: holder.data
+    signal back
+
+    Item {
+        id: header
+        anchors { top: parent.top; left: parent.left; right: parent.right }
+        height: 44
+
+        Rectangle {
+            id: backBtn
+            anchors { left: parent.left; verticalCenter: parent.verticalCenter }
+            width: 32; height: 32; radius: 16
+            color: backArea.containsMouse ? Qt.alpha(Theme.accent, 0.22) : "transparent"
+
+            Text {
+                anchors.centerIn: parent
+                text: ""
+                font { family: Theme.fontFamily; pixelSize: 14 }
+                color: Theme.text
+            }
+
+            MouseArea {
+                id: backArea
+                anchors.fill: parent
+                hoverEnabled: true
+                cursorShape: Qt.PointingHandCursor
+                onClicked: page.back()
+            }
+        }
+
+        Text {
+            anchors { left: backBtn.right; leftMargin: 10; verticalCenter: parent.verticalCenter }
+            text: page.title
+            font { family: Theme.fontFamily; pixelSize: Theme.fontSize + 2; bold: true }
+            color: Theme.text
+        }
+    }
+
+    Rectangle {
+        id: rule
+        anchors { top: header.bottom; left: parent.left; right: parent.right }
+        height: 1
+        color: Qt.alpha(Theme.text, 0.12)
+    }
+
+    ScrollView {
+        anchors { top: rule.bottom; left: parent.left; right: parent.right; bottom: parent.bottom }
+        anchors.topMargin: 12
+        clip: true
+        contentWidth: availableWidth
+
+        Item {
+            id: holder
+            width: parent.width
+            implicitHeight: childrenRect.height
+        }
+    }
+}
-- 
cgit v1.2.3